****

**Paradigma Funcional**

**Módulo 3:**

**Modelado de información**

**por Fernando Dodino**

**Carlos Lombardi**

**Nicolás Passerini**

**Daniel Solmirano**

**Revisión: Lucas Spigariol**

**Versión 2.1**

**Abril 2018**

Distribuido bajo licencia [Creative Commons Share-a-like](https://creativecommons.org/licenses/by-sa/4.0/legalcode)

**Contenido**

[1 Introducción](#_gb1hpspeej0s)

[2 Listas](#_xwukw6kc2lnr)

[2.1 Definición](#_nlp96qdnp7oy)

[2.2 Formas de generar una lista](#_cqu0iio54dpg)

[2.3 Pattern matching sobre listas](#_rkeb5q1444o5)

[2.4 Ejercitando pattern matching sobre listas](#_1wsis5w2q9aj)

[2.5 Ejemplo didáctico](#_cfy62b5tusom)

[2.6 Funciones que aplican sobre listas](#_txedc4ik0sos)

[2.6.1 Head: cabeza de una lista](#_a4hqql8pfp3l)

[2.6.2 Tail: cola de una lista](#_7wlq967qmbca)

[2.6.3 Otras funciones](#_bn51gap8wqnv)

[3 Tuplas](#_x2xuqlkw85oe)

[3.1 Definición](#_9wzqu4w4ew63)

[3.2 Pattern matching sobre tuplas](#_crgrv56kuog5)

[3.3 Ejemplos de tuplas](#_k8xkr1e9mqwk)

[3.4 Comparación entre tuplas y listas](#_1idtogww8fsj)

[3.5 Funciones que aplican sobre tuplas](#_9xx1sd9xctea)

[3.5.1 Sinónimos de tipo](#_o33sq9a8e83k)

[3.5.2 Definición de una función con tuplas](#_t8762shh5kfd)

[3.6 El menor de un par](#_lpx82rdbzz5y)

[4 Tipos propios](#_8ate7guv67e3)

[4.1 Definición](#_5qxntae8g2p6)

[4.2 Pattern matching sobre data](#_j4qsjop4csjc)

[4.3 Diferencias entre data y tupla](#_huvtyiystlmd)

[4.4 Repaso de acoplamiento](#_18au0h498n3w)

[4.5 Record syntax](#_m4i45clf6yr8)

[4.6 Cómo definir una persona con record syntax](#_3anfmzefdcp2)

[4.7 Funciones “adquiridas” con record syntax](#_dyh65qy5kt9s)

[4.8 Mostrar personas en la consola](#_jzbd3nf4qv11)

[4.9 Múltiples constructores](#_7ril25fixrb6)

[5 Ejercicio integrador](#_r1hxee7v5434)

[5.1 Alumnos](#_8kc92ebwb25v)

[5.2 Requerimientos](#_amgf6vbrq1vy)

[5.3 Modelar un parcial](#_isuii3sk2ye9)

[5.4 Modelar el tipo del criterio de estudio](#_fjk0y3o1in02)

[5.5 Modelar un alumno genérico](#_scmthodqiouq)

[5.6 Representar los criterios de estudio enunciados](#_tkwmznxmcsoj)

[5.7 Modelar a Nico, un alumno estudioso](#_bgxelu86h3hu)

[5.8 Nico pasa de estudioso a hijo del rigor](#_w5zi5xd5k7d1)

[5.9 Saber si un alumno va a estudiar para el parcial de Paradigmas](#_iu984cn0aojv)

[6 Resumen](#_37peulg4f5c6)

# 

# 

# 1 Introducción

Hasta el momento hemos conocido tipos de datos simples (los números con y sin decimales, los valores booleanos, los caracteres), algunos compuestos (como las cadenas de caracteres o strings) y también las funciones como tipos de dato. Para modelar información, ampliaremos el universo conocido a tres tipos de dato compuestos:

* las listas
* las tuplas
* y los tipos de dato definidos por el usuario

# 2 Listas

## 2.1 Definición

Una lista es una serie de elementos del mismo tipo. En esa serie puede no haber elementos, en ese caso la lista es vacía. Son útiles para modelar las materias aprobadas por un alumno, las mascotas que tiene una persona, los empleados de una compañía, etc.

## 2.2 Formas de generar una lista

La forma más sencilla de generar una lista es enumerar los elementos encerrados entre corchetes y separar cada elemento mediante una coma

[**1**, **2**, **3**]  
["Hola", "mundo"]

Los strings son literales especiales que se encierran entre comillas dobles:

"Hola" ==> lista de caracteres ≣ ['H', 'o', 'l', 'a']

En una lista de Haskell todos los elementos deben ser homogéneos, de lo contrario se generará un mensaje de error:

λ[[1]](#footnote-0) [ "hola", **True**]  
**Couldn't match expected type ‘[Char]’ with actual type ‘Bool’  
In the expression: True  
In the expression: ["hola", True]**

En el caso de las listas numéricas, se puede generar una lista de enteros especificando cota inferior y superior:

λ [**1**..**10**]  
[**1**,**2**,**3**,**4**,**5**,**6**,**7**,**8**,**9**,**10**]

También podemos definir una serie numérica de enteros a partir del primer número, el siguiente y la cota superior:  
λ [**1**, **3**..**16**]  
[**1**,**3**,**5**,**7**,**9**,**11**,**13**,**15**]

El rango puede ser ascendente o descendente (dependiendo del segundo número y las cotas inferior o superior):  
λ [**8**, **7**.. -**2**]  
[**8**,**7**,**6**,**5**,**4**,**3**,**2**,**1**,**0**,-**1**,-**2**]

E incluso podemos definir una lista infinita:

λ [**1**..]  
[**1**,**2**,**3**,**4**,**5**,**6**,**7**..

## 2.3 Pattern matching sobre listas

Existen varios patrones para trabajar las listas:

|  |  |
| --- | --- |
| **Pattern** | **Denota** |
| [] | Lista vacía, no se puede separar en cabeza y cola |
| (x:xs) | El operador : separa cabeza y cola de una lista.  Lista que tiene al menos un elemento, donde la cabeza es un elemento x, y la cola es una lista (son muchos x, por eso la convención es xs). Algunos ejemplos:   * para [1, 2, 3] la cabeza es 1, la cola es la lista [2, 3]. * para [1] la cabeza es 1, la cola es [ ] (lista vacía) * para lista vacía, no hay pattern matching posible (una lista vacía no se puede separar en cabeza y cola) |
| (x:y:ys) | Lista de al menos 2 elementos. Algunos ejemplos:   * [1, 2, 3], entonces x = 1, y = 2, ys = [3] * [1, 2, 3, 4], entonces x = 1, y = 2, ys = [3, 4] * [1, 2], x = 1, y = 2, ys = [ ] * [1], [ ] no producen pattern matching |
| [x] | Lista de exactamente un elemento. Algunos ejemplos:   * para [1] x es 1 * para [1, 2] no hay pattern matching * tampoco hay pattern matching para lista vacía |
| [x, y] | Lista de exactamente dos elementos. Algunos ejemplos:   * para [1, 2] x = 1, y = 2 * para [ ] , [1], [1, 2, 3] no hay pattern matching |

## 2.4 Ejercitando pattern matching sobre listas

Encontrar la cabeza y la cola de estas listas.

|  |  |  |
| --- | --- | --- |
| Lista | Cabeza | Cola |
| [1, 4] | 1 | [4] ojo, no es 4, es la lista compuesta por 4 |
| [] | No existe, no se puede dividir | |
| [[1, 7], [8, 7, 5], []] | [1, 7] sí, es una lista | [[8, 7, 5], []]. Se puede usar listas de listas |
| [8, "hermanos"] | No es una lista posible en este lenguaje que define una lista como un tipo de dato recursivo, compuesto por elementos del mismo tipo. | |

## 2.5 Ejemplo didáctico

Para fijar el concepto llamamos a cuatro personas, cada una representa un valor distinto 1, 2, 3 y 4:



¿Qué lista se forma? [1, 2, 3, 4],

¿cuál es la cabeza? 1, ¿cuál es la cola? [2, 3, 4] (que se lee "la lista compuesta por 2, 3 y 4")

Bien, el que estaba en la cabeza se va a sentar y seguimos con la lista resultante. ¿Cuál es la cabeza y cuál es la cola? 2, y [3, 4]. Lo importante es recalcar que la cola **siempre** es una lista: [3,4] se divide en cabeza 3 y cola [4] ("la lista compuesta por 4"). Y [4] es una lista cuya cabeza es 4 y la cola es la lista vacía.

Entonces, la lista con los números [1, 2, 3] puede escribirse:

(**1:**[**2**, **3**]) **=** (**1:**(**2:**[**3**])) **=** (**1:**(**2:**(**3:[]**)))

## 2.6 Funciones que aplican sobre listas

### 2.6.1 Head: cabeza de una lista

La función head/1 devuelve la cabeza de una lista.

**Main**> head [**1**, **7**, **9**]   
**1**

Implementamos la función aplicando pattern matching:

**head** (x**:**xs) **=** x

Como xs no nos interesa utilizarlo en la función, podemos utilizar la variable anónima (que se denota con el símbolo guión bajo o *underscore*):

**head** (x**:\_**) **=** x

¿Qué tipo de lista podemos recibir? Algunas pruebas en consola:

λ head ["hola" , "mundo"]  
"hola"  
  
λ head [**[]**, [**1**,**2**], [**3**, **4**]]  
**[]**

Podemos recibir listas de cualquier tipo:

**head** **::** [a] **->** a

y devolverá la cabeza de esa lista, que será del mismo tipo que el resto de los elementos.

### 2.6.2 Tail: cola de una lista

De la misma manera tenemos la función que devuelve la cola de una lista:

**tail** (\_**:xs**) **=** **xs**

¿De qué tipo es la función tail?

**tail** **::** [a] **->** [a]

### 2.6.3 Otras funciones

Existen otras funciones que desarrollaremos próximamente, pero que ya podemos usar[[2]](#footnote-1):

|  |  |  |
| --- | --- | --- |
| **Función** | **Objetivo** | **Ejemplo de uso** |
| length | Devuelve la longitud de una lista | λ length [**2**..**4**] **3** |
| sum | Suma los elementos de una lista de números | λ sum [**4**, **9**, **1**] **14** |
| (++) | Concatena dos listas | λ [**3**..**5**] ++ [**4**, **6**] [**3**,**4**,**5**,**4**,**6**] |
| take | Toma los primeros n elementos de la lista | λ take **3** [**4**..**11**] [**4**,**5**,**6**] |
| drop | Devuelve la lista sin los primeros n elementos | λ drop **2** "CIENCIA" "ENCIA" |
| (!!) | Devuelve el elemento que está en la posición n (donde 0 es el primer elemento) | λ [**1**..**10**] !! **3** **4**  λ **["buen", "dia", "gente", "como", "andan"] !! 2**  **"gente"** |
| reverse | Devuelve una lista con los elementos en orden inverso | λ reverse "ANITA LAVA LA TINA" "ANIT AL AVAL ATINA" |

# 3 Tuplas

## 3.1 Definición

Las tuplas permiten representar un tipo de dato compuesto, pero con elementos que pueden ser de distinto tipo. El número de elementos es fijo (siempre el mismo).

(**23**, **02**, **1973**) => tupla de 3 elementos para representar una fecha  
("Juan", **23**) => tupla de 2 elementos para representar una persona

Una tupla es un tipo de dato compuesto donde

(x1, x2.. xn) tiene tipos t1, t2… tn

## 3.2 Pattern matching sobre tuplas

No son muchos los patrones que describen tuplas

|  |  |
| --- | --- |
| **Pattern** | **Denota** |
| (x, y) | Tupla de dos elementos, x e y pueden tomar valores de cualquier tipo |
| (x, y, z) | Tupla de tres elementos, x, y, z pueden tomar valores de cualquier tipo |

## 3.3 Ejemplos de tuplas

Algunos ejemplos de tuplas: ¿De qué tipo son?

|  |  |
| --- | --- |
| **Tupla** | **Tipo de la tupla** |
| (1, [2], 3) | (Int, [Int], Int) |
| ('a', False) | (Char, Bool) |
| ((1,2),(3,4)) | ((Int, Int), (Int, Int)) |

## 3.4 Comparación entre tuplas y listas

* Las listas requieren que todos los elementos sean homogéneos: no podemos mezclar en una misma lista números y strings. Las tuplas pueden ser heterogéneas.
* El número de elementos de una lista es variable, puede ser infinito. En una tupla el número de elementos es fijo.
* La lista es un tipo de dato recursivo, la tupla no, aunque ambos son compuestos.

## 3.5 Funciones que aplican sobre tuplas

Hay funciones estándar para separar una tupla de dos elementos: *fst* devuelve el primer elemento de la tupla, *snd* devuelve el segundo elemento.

**fst** (a, **\_**) **=** a  
**snd** (**\_**, b) **=** b

¿De qué tipo son?

**fst** **::** (a,b) **->** a  
**snd** **::** (a,b) **->** b

Veamos un ejemplo de uso en la consola:

λ snd ("Laura", **True**)  
**True**  
λ snd ("Laura", (**30**, **6**))  
(**30**,**6**)

En el segundo ejemplo, vemos que la tupla puede contener como elemento otra tupla (que represente, por ejemplo, la fecha de cumpleaños). También podríamos usar una lista, para representar un alumno con sus notas:

**tobi** **=** ("Tobias Sandler", [**4**, **8**, **9**])

Pero en lugar de utilizar snd, podemos definir una función notas, que es mucho más representativo del dominio que estamos modelando[[3]](#footnote-2):

**notas** (**\_**, n) **=** n

o aun mejor, utilizando la igualdad en el sentido matemático:

**notas** **=** snd

λ notas **tobi**

[**4**, **8**, **9**]

Esto es algo a tener en cuenta a la hora de elegir una tupla como forma de representar información de nuestro negocio.

### 3.5.1 Sinónimos de tipo

El requerimiento que nos piden es “modelar la suma entre números complejos”. La primera decisión que tomamos es que usaremos una tupla para representar un número complejo.

Definimos entonces un sinónimo de tipo, para decir que existen los números complejos, de la siguiente manera:

**type** **Complejo** **=** (**Float**, **Float**)

### 3.5.2 Definición de una función con tuplas

Escribimos el tipo que tiene la función que suma complejos:

**sumarComplejos** **::** **Complejo** **->** **Complejo** **->** **Complejo**

Codificamos la función:

**sumarComplejos** (real1, imaginario1) (real2, imaginario2) **=**  
 (real1 + real2, imaginario1 + imaginario2)

Y por último lo probamos en la consola:

λ sumarComplejos (**1**, **2**) (**4**, -**1**)  
(**5.0**, **1.0**)

## 3.6 El menor de un par

Otra función que calcule el menor de un par de números puede ser escrito así:

**minPar** (a, b) **=** min a b

# 4 Tipos propios

## 4.1 Definición

Se pueden definir nuevos tipos de datos que se agregan a los ya existentes en el lenguaje, mediante la expresión data". Si queremos modelar varias personas que tienen nombre y edad, lo hacemos de la siguiente manera:

**data** **Persona** **=** **Persona** **String** **Int**

Esto se lee como: “el tipo de dato Persona (en azul) utiliza un constructor –de nombre Persona, en rojo- que recibe un String y un Int”.

## 4.2 Pattern matching sobre data

Para poder reconocer un tipo de dato propio usamos el constructor: en el caso **Persona** "Santiago" **32**,

el primer parámetro (String que representa el nombre) se asocia a "Santiago" y el segundo (Int que representa la edad) a **32**

De esta manera podemos definir las funciones que permiten conocer el nombre y la edad:

**nombre** (**Persona** n e) **=** n  
**edad** (**Persona** n e) **=** e

Tener en cuenta la línea de la definición “data”, más arriba. La sintaxis de una persona no requiere paréntesis pero, al igual que pasaba con las listas, para decir “todo esto es un único parámetro” vamos a necesitar usarlos.

Lo evaluamos en Haskell:

λ nombre (**Persona** "Miguel" **34**)  
"Miguel"

## 4.3 Diferencias entre data y tupla

¿Qué diferencias hay entre modelar una persona como una tupla o como un data? ¿Qué tipo espera la función nombre?

**nombre** **::** **Persona** **->** [**Char**]

Una persona, mientras que la definición de nombre = fst nos da

**fst** **::** (a,b) **->** a

Relacionado con esto: la tupla ofrece una solución general que sirve para modelar personas, empleados y muchas otras cosas. Justamente por eso no es intuitiva, la estructura tiene que ser conocida por quien la usa: tengo una tupla con dos elementos String e Int, no es fácil darse cuenta de que se trata de una estructura que modela una persona, donde el primer elemento se asocia al nombre y el segundo elemento a la edad.

Para invocar a la función nombre, necesitamos construir primero un valor de tipo Persona, esto lo hacemos mediante el constructor Persona:

λ **:**t **Persona** "Miguel" **34**  
**Persona** "Miguel" **34** **::** **Persona**

De hecho la aplicación parcial funciona perfectamente:

λ **:**t **Persona** "Miguel"  
**Persona** "Miguel" **::** **Int** **->** **Persona**

Es decir, Persona “Miguel” es una función que espera la edad y devuelve una persona.

## 4.4 Repaso de acoplamiento

Recordemos la función que resuelve el requerimiento “Saber si una persona es mayor de edad”:

**esMayorEdad** **::** **Persona** **->** **Bool**  
**esMayorEdad** **=** mayorDeEdad . edad

Con la nueva definición de Persona como registro, no tenemos cambios en la función esMayorEdad



lo cual sigue demostrando que hay un buen grado de acoplamiento entre

* las funciones esMayorEdad y edad
* la función esMayorEdad y la definición de Persona (antes tupla, hoy data)

## 4.5 Record syntax

Se agrega información adicional a la persona:

* el domicilio, que vamos a modelar con un String
* el número de teléfono, un nuevo String
* la fecha de nacimiento, que puede ser una tupla de tres elementos
* si es buena persona, un booleano
* y la cantidad de plata que tiene en el bolsillo, un número con decimales

El constructor Persona se vuelve bastante menos expresivo:

**data** **Persona** **=** **Persona** **String** **Int** **String** **String** (**Int**, **Int**, **Int**) **Bool** **Float**

sin contar que además necesitaremos funciones que se incorporan a nombre y edad...

**domicilio** **::** **Persona** **->** **String**  
**domicilio** (**Persona** **\_** **\_** dom **\_** **\_** **\_** **\_**) **=** dom

... y lo mismo con cada uno de los datos que componen la estructura. Para sumar expresividad y evitar definiciones que podríamos considerar “redundantes”, tenemos la notación *record syntax* que consiste en definir Persona de la siguiente manera:

**data** **Persona** **=** **Persona** {  
 nombre **::** **String**,  
 edad **::** **Int**,  
 domicilio **::** **String**,  
 telefono **::** **String**,  
 fechaNacimiento **::** (**Int**, **Int**, **Int**),  
 buenaPersona **::** **Bool**,  
 plata **::** **Float**  
}

## 4.6 Cómo definir una persona con record syntax

Para crear una persona podemos utilizar el mismo formato que utilizamos anteriormente

**juan = Persona "Juan" 29 "Ayacucho 554" "45232598" (17,7,1988) True 30.0**

Esto como vemos

* es una definición propensa a cometer errores
* tiene poca expresividad, no siempre los valores revelan de qué información se trata
* nos obliga a cargar la información respetando el orden que definió el tipo de dato

Pero como el tipo de dato Persona está definido con *record syntax*, tenemos una alternativa para modelar a Juan:

**juan** **=** **Persona** {  
 nombre **=** "Juan",  
 edad **=** **29**,  
 domicilio **=** "Ayacucho 554",  
 telefono **=** "45232598",  
 fechaNacimiento **=** (**17**,**7**,**1988**),  
 buenaPersona **=** **True**,  
 plata **=** **30.0**  
}

No solo es más expresiva la forma de definir la información, sino que también podemos alterar el orden en el que definimos los valores de juan:

**juan** **=** **Persona** {  
 nombre **=** "Juan",  
 telefono **=** "45232598",  
 domicilio **=** "Ayacucho 554",  
 fechaNacimiento **=** (**17**,**7**,**1988**),  
 buenaPersona **=** **True**,  
 edad **=** **29**,  
 plata **=** **30.0**  
}

## 4.7 Funciones “adquiridas” con record syntax

Al definir una Persona con la sintaxis de record, adquirimos funciones que permiten preguntar por las propiedades de una persona:

λ telefono juan  
"45232598"  
λ domicilio juan  
"Ayacucho 554"

No necesitamos ni podemos escribir definiciones de la función telefono, edad ni domicilio. Estas están implícitas por la definición del tipo de dato Persona:

λ **:**t edad  
**edad** **::** **Persona** **->** **Int**

## 4.8 Mostrar personas en la consola

Si intentamos visualizar a Juan en la consola, aparece un mensaje de error:

λ juan  
**<interactive>:14:1:  
 No instance for (Show Persona) arising from a use of ‘print’  
 In a stmt of an interactive GHCi command: print it**

Si bien más adelante estaremos estudiando en detalle el sistema de tipos de Haskell, podemos explicar brevemente que una Persona no se puede mostrar si no se define como instancia de Show. Para solucionar este error, basta con incorporar este agregado a nuestra definición de Persona:

**data** **Persona** **=** **Persona** {  
 nombre **::** **String**,  
 edad **::** **Int**,  
 domicilio **::** **String**,  
 telefono **::** **String**,  
 fechaNacimiento **::** (**Int**, **Int**, **Int**),  
 buenaPersona **::** **Bool**,  
 plata **::** **Float**  
} **deriving** (**Show**)

Ahora sí, podemos evaluar en la consola a Juan:

λ juan  
**Persona** {nombre **=** "Juan", edad **=** **29**, domicilio **=** "Ayacucho 554", telefono **=** "45232598", fechaNacimiento **=** (**17**,**7**,**1988**), buenaPersona **=** **True**, plata **=** **30.0**}

## 4.9 Múltiples constructores

Es posible definir un tipo de dato propio que admita más de un constructor. Por ejemplo podemos definir

**data** **Sexo** **=** **Femenino** | **Masculino**

Esto se lee: “el tipo de dato Sexo tiene dos constructores: Femenino y Masculino, ambos sin parámetros”. Entonces podemos construir una función que discrimine ambos elementos por pattern matching

**edadJubilatoria** **::** **Sexo** **->** **Int**  
**edadJubilatoria** **Femenino** **=** **60**  
**edadJubilatoria** **Masculino** **=** **65**

Si en una agencia de remises tenemos

* autos propios, de los cuales sabemos el consumo en litros cada 10 kms
* y autos contratados, de los cuales sabemos la empresa que nos provee el auto y el costo directo por kilómetro que nos cobra

Esto puede traducirse a

**data** **Vehiculo** **=** **Propio** **Int** | **Contratado** **String** **Int**

Podemos tener en una misma lista vehículos propios y contratados:  
**type** **Flota** **=** [**Vehiculo**]  
**vehiculos** **::** **Flota**

**vehiculos** **=** [**Propio** **9**, **Propio** **15**, **Contratado** "Remixes" **4**, **Propio** **12**]

Cómo calculamos el costo por kilómetro:

* en el caso de los vehículos propios, es el consumo en litros / 10 \* el valor del litro de nafta
* en el caso de los vehículos contratados, es dicho valor

**valorLitroNafta** **::** **Float**  
**valorLitroNafta** **=** **16.5**  
  
**costoPorKm** **::** **Vehiculo** **->** **Float**  
**costoPorKm** (**Propio** consumo) **=** **valorLitroNafta** \* (consumo / **10**)

**costoPorKm** (**Contratado** **\_** costo) **=** costo

# 5 Ejercicio integrador

Hasta aquí ya conocemos una amplia variedad de valores que nos pueden ayudar a modelar información

* **simples:** números, booleanos, caracteres... y no nos olvidemos de las *funciones* que también son valores posibles
* **compuestos:** strings, listas, tuplas, data

## 5.1 Alumnos

Modelar un alumno, que define

* un nombre,
* la fecha de nacimiento,
* el legajo (sin dígito verificador),
* las materias que cursa
* y el criterio para estudiar ante un parcial:
  + algunos son estudiosos: estudian siempre,
  + otros son hijos del rigor: estudian si el parcial tiene más de *n* preguntas,
  + y también están los cabuleros, que estudian si la materia tiene una cantidad impar de letras.

## 5.2 Requerimientos

1. Modelar un parcial
2. Modelar el tipo que representa el criterio de estudio.
3. Modelar genéricamente un alumno.
4. Representar con la abstracción que crea más conveniente al criterio estudioso, hijo del rigor y cabulero.
5. Modelar a Nico, un alumno estudioso
6. Hacer que Nico pase de ser estudioso a hijo del rigor (buscar una abstracción lo suficientemente genérica)
7. Determinar si Nico va a estudiar para el parcial de Paradigmas

## 5.3 Modelar un parcial

Para resolver este requerimiento, tenemos que abstraer la información necesaria para poder resolver lo que hoy nos piden. Ciertamente, hay mucha información que un parcial puede tener:

* hora de comienzo
* hora de fin
* el profesor que lo toma
* la materia
* el aula
* la cantidad de alumnos presentes
* la cantidad de preguntas
* las preguntas propiamente dichas...

... entre otros datos. Pero en este enunciado, solamente nos importan dos cosas: la materia (para los cabuleros) y la cantidad de preguntas que tiene un parcial (para los hijos del rigor).

Esta técnica que empleamos toma en cuenta lo que nos interesa y descarta lo que no es esencial para la solución, proceso que se suele llamar **abstracción**.

* ¿Cómo modelamos la materia? No necesitamos que sea una estructura compuesta, nos alcanza con que sea un String.
* Respecto a las preguntas, tampoco necesitamos conocer la lista de preguntas concreta, nos basta con saber la cantidad por el momento, entonces un entero es suficiente.

Describimos un Parcial como:

**data** **Parcial** **=** **Parcial** **String** **Int** **deriving** (**Show**)

¿Podría ser el parcial una tupla? Sí, y eso nos hubiera permitido usar fst / snd para obtener la materia / la cantidad de preguntas. Pero hemos visto que no es lo suficientemente expresiva esa solución, así que construiremos nuestras propias funciones (o bien podemos escribir al Parcial con *record syntax*):

**materia** (mat, **\_**) **=** mat  
**cantidadPreguntas** (**\_**, cant) **=** cant

## 5.4 Modelar el tipo del criterio de estudio

¿Qué representa el criterio? Dado un parcial, queremos saber si va a estudiar. Es decir:

**Parcial** **->** **Bool**

Exacto, el criterio se modela con una función, que va a formar parte de la estructura de un alumno. Por eso no queremos usar:

* códigos numéricos (1 = estudia siempre, 2 = hijo del rigor, 3 = cabulero)
* ni códigos alfabéticos (“ES”, “HR”, “CA”)
* ni ningún otro mecanismo de indirección: en la estructura del alumno debe estar el criterio que nos diga si va a estudiar ante un parcial.

Para definir el tipo, escribimos

**type** **CriterioEstudio** **=** **Parcial** **->** **Bool**

## 5.5 Modelar un alumno genérico

Un alumno se puede representar como una estructura

* con tuplas
* o bien con un tipo de dato propio (*data*)

Dada la gran cantidad de información que se asocia a un alumno, vamos a elegir definir un tipo de dato propio con notación de registro (*record syntax*).

La siguiente decisión es analizar de qué tipo es cada uno de los datos del alumno:

* el nombre se modela con un String
* la fecha de nacimiento, con una tupla (aunque podría ser un data también)
* el legajo sin el dígito verificador se puede modelar con un Int
* las materias que cursa: no necesitamos representar a la materia como una entidad compuesta, así que con una lista de strings nos alcanza
* el criterio de estudio ya está modelado como una función

Escribimos:

**data** **Alumno** **=** **Alumno** {  
 nombre **::** **String**,  
 fechaNacimiento **::** (**Int**, **Int**, **Int**),  
 legajo **::** **Int**,  
 materiasQueCursa **::** [**String**],  
 criterioEstudio **::** **CriterioEstudio**  
} **deriving** (**Show**)

## 5.6 Representar los criterios de estudio enunciados

Definimos entonces tres funciones:

El estudioso que siempre estudia (no importa el parcial):

**estudioso** **::** **CriterioEstudio**  
**estudioso** **\_** **=** **True**

El hijo del rigor, al que le podemos configurar la cantidad de preguntas por sobre las cuales comienza a estudiar:  
**hijoDelRigor** **::** **Int** **->** **CriterioEstudio**  
**hijoDelRigor** n (**Parcial** **\_** preguntas) **=** preguntas > n

Y el cabulero que depende de que la materia tenga una cantidad impar de letras:  
**cabulero** **::** **CriterioEstudio**  
**cabulero** (**Parcial** materia **\_**) **=** (odd . length) materia[[4]](#footnote-3)

## 5.7 Modelar a Nico, un alumno estudioso

Aprovechamos la definición anterior de estudioso para escribir a la expresión que describe a Nico:

**nico** **=** **Alumno** {  
 fechaNacimiento **=** (**10**, **3**, **1993**),  
 nombre **=** "Nico",  
 materiasQueCursa **=** ["sysop", "proyecto"],  
 criterioEstudio **=** estudioso,  
 legajo **=** **124124**  
}

Evaluamos nico por consola y nos aparece un error:

**No instance for (Show CriterioEstudio)**

**arising from the fifth field of `Alumno' (type `CriterioEstudio')**

**Possible fix:**

**use a standalone 'deriving instance' declaration,**

**so you can specify the instance context yourself**

**When deriving the instance for (Show Alumno)**

Al igual que nos pasaba con el alumno, necesitamos decirle cómo mostrar las funciones en la consola. La solución, incorporamos esta línea al comienzo de nuestro .hs:

**import** **Text.Show.Functions**

Y ahora sí podemos ver representado a nico en consola:

λ nico

**Alumno** {

nombre **=** "Nico",

fechaNacimiento **=** (**10**,**3**,**1993**),

legajo **=** **124124**,

materiasQueCursa **=** ["sysop","proyecto"],

criterioEstudio **=** <function>

}

## 5.8 Nico pasa de estudioso a hijo del rigor

Como dentro del paradigma funcional queremos trabajar sin efecto colateral, no podemos modificar directamente a Nico, sino que **tenemos que generar una transformación que tome a un estudiante y devuelva un nuevo estudiante modificado**.

Por eso generaremos una función cambiarCriterioEstudio:



Una primera forma de resolverlo puede ser:

**cambiarCriterioEstudio** nuevoCriterio alumno **=** **Alumno** {  
 nombre **=** nombre alumno,  
 fechaNacimiento **=** fechaNacimiento alumno,  
 legajo **=** legajo alumno,  
 materiasQueCursa **=** materiasQueCursa alumno,  
 criterioEstudio **=** nuevoCriterio  
}

Lo que resulta un tanto tedioso. Otra alternativa podría ser crear el nuevo alumno respetando el orden de la información definida en el tipo de dato:

**cambiarCriterioEstudio** nuevoCriterio alumno **=** **Alumno**   
 (nombre alumno) (fechaNacimiento alumno)  
 (legajo alumno) (materiasQueCursa alumno) nuevoCriterio

O con pattern matching

**cambiarCriterioEstudio** nuevoCriterio

(Alumno nombre fecha legajo materias \_)

**=** **Alumno** nombre fecha legajo materias nuevoCriterio)

Una tercera opción permite generar un nuevo alumno indicando sólo lo que cambia[[5]](#footnote-4):

**cambiarCriterioEstudio** nuevoCriterio alumno **=** alumno {

criterioEstudio **=** nuevoCriterio

}

En la parte derecha de la función no estamos usando el constructor Alumno, sino la variable alumno que recibimos como parámetro.

¿De qué tipo es cambiarCriterioEstudio?

**cambiarCriterioEstudio** **::** **CriterioEstudio** **->** **Alumno** **->** **Alumno**

Para pasar a Nico a ser hijo del rigor, necesitamos definir el mínimo de preguntas, de lo contrario no va a pasar el chequeo de tipos que hace el compilador Haskell:

λ cambiarCriterioEstudio hijoDelRigor nico  
 **Couldn't match type `Int' with `Parcial'   
 Expected type: CriterioEstudio   
 Actual type: Int -> CriterioEstudio   
 Probable cause: `hijoDelRigor' is applied to too few arguments   
 In the first argument of `cambiarCriterioEstudio', namely   
 `hijoDelRigor'   
 In the second argument of `($)', namely   
 `cambiarCriterioEstudio hijoDelRigor nico'**

Exacto, hijoDelRigor es una función que va de Int a CriterioEstudio, es decir, de Int a Parcial -> Bool. Corregimos entonces esto utilizando aplicación parcial:

λ cambiarCriterioEstudio (hijoDelRigor **5**) nico  
**Alumno** {

nombre **=** "Nico",

fechaNacimiento **=** (**10**,**3**,**1993**),

legajo **=** **124124**,

materiasQueCursa **=** ["sysop","proyecto"],

criterioEstudio **=** <function>

}

Todavía no se aprecia que devuelve es una función diferente.

## 5.9 Saber si un alumno va a estudiar para el parcial de Paradigmas

Ok, necesitamos

* un alumno: podemos usar Nico
* un parcial de Paradigmas

Si estudia o no dependerá del criterio del alumno. Entonces:



**estudia :: Parcial** **->** **Alumno** **->** **Bool**  
**estudia** parcial alumno **=** (criterioEstudio alumno) parcial

Podemos transformar a Nico de estudioso a hijo del rigor con 5 preguntas y luego preguntar si estudia para el parcial de PDP que tiene 3 preguntas:

**parcialPDP** **=** **Parcial** "PDP" **3**

λ (estudia parcialPDP . cambiarCriterioEstudio (hijoDelRigor **5**)) nico  
**False**

λ (estudia parcialPDP . cambiarCriterioEstudio (hijoDelRigor **2**)) nico  
**True**

# 6 Resumen

A lo largo de este extenso capítulo hemos incorporado a las listas, las tuplas y los data como formas de modelar información compuesta, que se suman a los números, los caracteres, los booleanos, los strings y las funciones. Entonces, podemos combinar las abstracciones en una estructura que representa una entidad, y operaciones asociadas a dicha estructura que pueden tener o no efecto colateral.

1. El símbolo λ se utiliza como prompt de la consola, como anteriormente se usó Main> o Prelude> [↑](#footnote-ref-0)
2. Para más información consultar la [guía de lenguajes](https://docs.google.com/document/d/1oJ-tyQJoBtJh0kFcsV9wSUpgpopjGtoyhJdPUdjFIJQ/edit?usp=sharing) [↑](#footnote-ref-1)
3. Lo que en alguna bibliografía se conoce como [*intention revealing*](https://martinfowler.com/bliki/BeckDesignRules.html) [↑](#footnote-ref-2)
4. Pregunta para el lector: ¿se puede usar notación point free aquí? ¿por qué (no)? [↑](#footnote-ref-3)
5. Agradecemos por este tip a Juan Ignacio Ferro, del curso de verano 2017. Atención: esta variante es válida sólo si se trabaja con *record syntax*. [↑](#footnote-ref-4)